Queries

Some helpful queries for researchers concerned by Nazi-looted art 

(note: Wikidata queries are presented where possible as short links. Other Sparql queries which do not provide short links are written out)

Wikidata

100 or so short links to Wikidata queries designed to facilitate the research into Nazi looted art (Google Sheets)

https://docs.google.com/spreadsheets/d/e/2PACX-1vRAwUD3eHud0-xLcw38MQGcEzB5y77NpPMy0IKy7Ww2EtUrHrLC96I6-op2nQms5dz8zPDVVWnp4LNf/pubhtml?gid=0&single=true

Additional Wikidata queries

Holocaust victim, art looting Red Flag name, Nazi party member, or persecuted person?

Table of contextual information about Art Market People

https://w.wiki/7gg3

Art Looting Investigation Unit Red Flag Names in Wikidata with External Identifiers Viaf, RKD, GND, BNF and Proveana

Table: https://www.openartdata.org/p/aliu-red-flag-list-with-viaf-gnd-bnf.html

Query: https://w.wiki/BNXt

Getty Museum Sparql endpoint

https://data.getty.edu/museum/collection/sparql-ui#

Sparql Query to get items that changed hands with filter on word or name

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

PREFIX la: <https://linked.art/ns/terms/>

PREFIX aat: <http://vocab.getty.edu/aat/>

PREFIX getty: <http://data.getty.edu/local/>

SELECT ?humanMadeObject ?humanMadeObjectLabel ?objLabel WHERE {

    ?humanMadeObject rdf:type crm:E22_Human-Made_Object;

                     crm:P24i_changed_ownership_through ?obj.

    

    ?obj rdfs:label ?objLabel .

  ?humanMadeObject rdfs:label ?humanMadeObjectLabel

    

    # Filtering on crm:P24i_changed_ownership_through that contains "Speelman"

    FILTER (CONTAINS(?objLabel, "Speelman"))

Sparql query to retrieve "Groups" with their Slug identifier

https://data.getty.edu/museum/collection/sparql-ui#

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

PREFIX la: <https://linked.art/ns/terms/>

PREFIX aat: <http://vocab.getty.edu/aat/>

PREFIX getty: <http://data.getty.edu/local/>

SELECT ?group ?groupLabel ?slug WHERE {

  ?group rdf:type crm:E74_Group. 

   ?group rdfs:label ?groupLabel.  

  ?group crm:P129i_is_subject_of ?slug.  

 # FILTER (?IDLabel = "Slug Identifier")

}

LIMIT 500

****

The Getty data structure can be complex. This query shows the uris and their label for a single item, which can be helpful in designing queries.

https://data.getty.edu/museum/collection/sparql-ui#

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

SELECT ?property ?value ?valueLabel WHERE {

  <https://data.getty.edu/museum/collection/object/04b051a9-92fa-4bea-95cd-b8657f319c39> ?property ?value.

  ?value rdfs:label ?valueLabel.

}

***

Acquisition: names associated with the acquisition of an item

https://data.getty.edu/museum/collection/sparql-ui#

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

SELECT ?acquisition ?acquisitionLabel?property ?value ?valueLabel WHERE {

  ?acquisition rdf:type crm:E8_Acquisition.

  ?acquisition ?property ?value.

  ?object ?rel ?acquisition.

  ?acquisition rdfs:label ?acquisitionLabel.

  ?value rdfs:label ?valueLabel.

  FILTER (?object = <https://data.getty.edu/museum/collection/object/04b051a9-92fa-4bea-95cd-b8657f319c39>)

  

}

***

Nested query getting the artist for a object after a search on an acquisition name

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

PREFIX la: <https://linked.art/ns/terms/>

PREFIX aat: <http://vocab.getty.edu/aat/>

PREFIX getty: <http://data.getty.edu/local/>

SELECT ?humanMadeObject ?humanMadeObjectLabel ?creatorName WHERE {

  {

    SELECT ?humanMadeObject ?humanMadeObjectLabel WHERE {

      ?humanMadeObject rdf:type crm:E22_Human-Made_Object;

                       crm:P24i_changed_ownership_through ?obj.

      ?obj rdfs:label ?objLabel .

      ?humanMadeObject rdfs:label ?humanMadeObjectLabel

      FILTER (CONTAINS(?objLabel, "Flechtheim"))

    } LIMIT 100

  }

  OPTIONAL {

    ?humanMadeObject crm:P108i_was_produced_by ?creationEvent .

    ?creationEvent crm:P14_carried_out_by ?creator .

    ?creator rdfs:label ?creatorName .

  }

}

***

Nested query which first filters for objects and then retrieves the names associated with the acquisition of those objects

https://data.getty.edu/museum/collection/sparql-ui#

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

SELECT ?humanMadeObject ?humanMadeObjectLabel ?acquisition ?acquisitionLabel ?property ?value ?valueLabel WHERE {

  {

    SELECT ?humanMadeObject ?humanMadeObjectLabel WHERE {

      ?humanMadeObject rdf:type crm:E22_Human-Made_Object;

                       crm:P24i_changed_ownership_through ?obj.

      ?obj rdfs:label ?objLabel .

      ?humanMadeObject rdfs:label ?humanMadeObjectLabel

      FILTER (CONTAINS(?objLabel, "Flechtheim"))

    } LIMIT 100

  }

  

  ?acquisition rdf:type crm:E8_Acquisition.

  ?acquisition ?property ?value.

  ?humanMadeObject ?rel ?acquisition.

  ?acquisition rdfs:label ?acquisitionLabel.

  OPTIONAL { ?value rdfs:label ?valueLabel. }

}

****

Nested Query

Getting information about the acquisition of objects associated with a selection of names

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>

SELECT ?humanMadeObject ?humanMadeObjectLabel ?acquisition ?acquisitionLabel ?property ?value ?valueLabel WHERE {

  {

    SELECT ?humanMadeObject ?humanMadeObjectLabel WHERE {

      ?humanMadeObject rdf:type crm:E22_Human-Made_Object;

                       crm:P24i_changed_ownership_through ?obj.

      ?obj rdfs:label ?objLabel .

      ?humanMadeObject rdfs:label ?humanMadeObjectLabel

      FILTER (CONTAINS(?objLabel, "Flechtheim") || CONTAINS(?objLabel, "thanhauser") || CONTAINS(?objLabel, "Katz"))

    } LIMIT 100

  }

  ?acquisition rdf:type crm:E8_Acquisition.

  ?acquisition ?property ?value.

  ?humanMadeObject ?rel ?acquisition.

  ?acquisition rdfs:label ?acquisitionLabel.

  OPTIONAL { ?value rdfs:label ?valueLabel. }

}